Perl version

Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

map

Perl 5 version 26.1 documentation
Go to top
Show recent pages
Recently read

map

Perl functions A-Z | Perl functions by category | The 'perlfunc' manpage
  • map BLOCK LIST

  • map EXPR,LIST

    Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each element) and returns the list value composed of the results of each such evaluation. In scalar context, returns the total number of elements so generated. Evaluates BLOCK or EXPR in list context, so each element of LIST may produce zero, one, or more elements in the returned value.

    1.     my @chars = map(chr, @numbers);

    translates a list of numbers to the corresponding characters.

    1.     my @squares = map { $_ * $_ } @numbers;

    translates a list of numbers to their squared values.

    1.     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;

    shows that number of returned elements can differ from the number of input elements. To omit an element, return an empty list (). This could also be achieved by writing

    1.     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;

    which makes the intention more clear.

    Map always returns a list, which can be assigned to a hash such that the elements become key/value pairs. See perldata for more details.

    1.     my %hash = map { get_a_key_for($_) => $_ } @array;

    is just a funny way to write

    1.     my %hash;
    2.     foreach (@array) {
    3.         $hash{get_a_key_for($_)} = $_;
    4.     }

    Note that $_ is an alias to the list value, so it can be used to modify the elements of the LIST. While this is useful and supported, it can cause bizarre results if the elements of LIST are not variables. Using a regular foreach loop for this purpose would be clearer in most cases. See also grep for a list composed of those items of the original list for which the BLOCK or EXPR evaluates to true.

    { starts both hash references and blocks, so map { ... could be either the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look ahead for the closing } it has to take a guess at which it's dealing with based on what it finds just after the {. Usually it gets it right, but if it doesn't it won't realize something is wrong until it gets to the } and encounters the missing (or unexpected) comma. The syntax error will be reported close to the }, but you'll need to change something near the { such as using a unary + or semicolon to give Perl some help:

    1.  my %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
    2.  my %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
    3.  my %hash = map {; "\L$_" => 1  } @array # this also works
    4.  my %hash = map { ("\L$_" => 1) } @array # as does this
    5.  my %hash = map {  lc($_) => 1  } @array # and this.
    6.  my %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
    8.  my %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)

    or to force an anon hash constructor use +{:

    1.     my @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
    2.                                               # comma at end

    to get a list of anonymous hashes each with only one entry apiece.