Tomcat入门了[共享]

以下是Netbeans5.0自带Tomcat服务器的启动文件startup.bat：
/////////////////////////////////////////////////////////////////////////////
@echo off
if "%OS%" == "Windows_NT" setlocal
rem ---------------------------------------------------------------------------
rem Start script for the CATALINA Server
rem
rem $Id: startup.bat,v 1.6 2004/05/27 18:25:11 yoavs Exp $
rem ---------------------------------------------------------------------------

rem Guess CATALINA_HOME if not defined
set CURRENT_DIR=%cd%
if not "%CATALINA_HOME%" == "" goto gotHome
set CATALINA_HOME=%CURRENT_DIR%
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set CATALINA_HOME=%cd%
cd %CURRENT_DIR%
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome

set EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat

rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find %EXECUTABLE%
echo This file is needed to run this program
goto end
:okExec

rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs

call "%EXECUTABLE%" start %CMD_LINE_ARGS%

:end
/////////////////////////////////////////////////////////
Netbeans里的Tomcat服务器只有在执行.jsp文件的时候才会被启，如果想单独启动Tomcat服务器就要找到Tomcat的路径，这个路径很容易找到，对于已经入了门的初学者来说可以看到Netbeans编译程序时的信息，在这里就会看到Tomcat所在路径（C:\Program Files\netbeans-5.0\enterprise2\jakarta-tomcat-5.5.9\)，而要启动Tomcat就要进入bin子目录下执行这个.bat文件。对于.bat文件的内容就要去熟悉DOS操作系统了。（也可以查看其它的.bat文件内容）
ApacheTomcat5.5.X启动后可以在浏览器内输入http://localhost:8080来测试服务器是否已经启动了。如果启动成功就会出现ApacheTomcat的页面。
其实在Tomcat的目录下还可以看到几个.sh文件，这就是用在Linux操作系统下的，比如startup.h就是Linux下的启动文件。
这时候就可以配置Tomcat服务器了，在conf目录下有几个.xml的文件就是用来对Tomcat进行配置的。在配置之前要给Tomcat添加一个管理用户，默认的情况下是没有管理用户的。找到conf目录下的tomcat-user.xml文件，在里面添加一行<user username="admin" password="xxxx" role="standard,manager"/>（这个格式即使不知道也可以按照原文件内容拼出来的）。
用户添加完成后就重新启动服务器，以使服务器配置生效。（最好也将浏览器重启一下，有可能会存在缓存问题）
如果想了解更多那就去读Tomcat文档罢，在locahost里当然就有，也就是说所以产品的自身文档是最好的教程。