Perl version

Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Math::BigInt

Perl 5 version 26.1 documentation
Go to top
Show page index • Show recent pages
Recently read

Math::BigInt

NAME

Math::BigInt - Arbitrary size integer/float math package

SYNOPSIS

  1.   use Math::BigInt;
  3.   # or make it faster with huge numbers: install (optional)
  4.   # Math::BigInt::GMP and always use (it falls back to
  5.   # pure Perl if the GMP library is not installed):
  6.   # (See also the L<MATH LIBRARY> section!)
  8.   # warns if Math::BigInt::GMP cannot be found
  9.   use Math::BigInt lib => 'GMP';
  11.   # to suppress the warning use this:
  12.   # use Math::BigInt try => 'GMP';
  14.   # dies if GMP cannot be loaded:
  15.   # use Math::BigInt only => 'GMP';
  17.   my $str = '1234567890';
  18.   my @values = (64, 74, 18);
  19.   my $n = 1; my $sign = '-';
  21.   # Configuration methods (may be used as class methods and instance methods)
  23.   Math::BigInt->accuracy();     # get class accuracy
  24.   Math::BigInt->accuracy($n);   # set class accuracy
  25.   Math::BigInt->precision();    # get class precision
  26.   Math::BigInt->precision($n);  # set class precision
  27.   Math::BigInt->round_mode();   # get class rounding mode
  28.   Math::BigInt->round_mode($m); # set global round mode, must be one of
  29.                                 # 'even', 'odd', '+inf', '-inf', 'zero',
  30.                                 # 'trunc', or 'common'
  31.   Math::BigInt->config();       # return hash with configuration
  33.   # Constructor methods (when the class methods below are used as instance
  34.   # methods, the value is assigned the invocand)
  36.   $x = Math::BigInt->new($str);         # defaults to 0
  37.   $x = Math::BigInt->new('0x123');      # from hexadecimal
  38.   $x = Math::BigInt->new('0b101');      # from binary
  39.   $x = Math::BigInt->from_hex('cafe');  # from hexadecimal
  40.   $x = Math::BigInt->from_oct('377');   # from octal
  41.   $x = Math::BigInt->from_bin('1101');  # from binary
  42.   $x = Math::BigInt->bzero();           # create a +0
  43.   $x = Math::BigInt->bone();            # create a +1
  44.   $x = Math::BigInt->bone('-');         # create a -1
  45.   $x = Math::BigInt->binf();            # create a +inf
  46.   $x = Math::BigInt->binf('-');         # create a -inf
  47.   $x = Math::BigInt->bnan();            # create a Not-A-Number
  48.   $x = Math::BigInt->bpi();             # returns pi
  50.   $y = $x->copy();         # make a copy (unlike $y = $x)
  51.   $y = $x->as_int();       # return as a Math::BigInt
  53.   # Boolean methods (these don't modify the invocand)
  55.   $x->is_zero();          # if $x is 0
  56.   $x->is_one();           # if $x is +1
  57.   $x->is_one("+");        # ditto
  58.   $x->is_one("-");        # if $x is -1
  59.   $x->is_inf();           # if $x is +inf or -inf
  60.   $x->is_inf("+");        # if $x is +inf
  61.   $x->is_inf("-");        # if $x is -inf
  62.   $x->is_nan();           # if $x is NaN
  64.   $x->is_positive();      # if $x > 0
  65.   $x->is_pos();           # ditto
  66.   $x->is_negative();      # if $x < 0
  67.   $x->is_neg();           # ditto
  69.   $x->is_odd();           # if $x is odd
  70.   $x->is_even();          # if $x is even
  71.   $x->is_int();           # if $x is an integer
  73.   # Comparison methods
  75.   $x->bcmp($y);           # compare numbers (undef, < 0, == 0, > 0)
  76.   $x->bacmp($y);          # compare absolutely (undef, < 0, == 0, > 0)
  77.   $x->beq($y);            # true if and only if $x == $y
  78.   $x->bne($y);            # true if and only if $x != $y
  79.   $x->blt($y);            # true if and only if $x < $y
  80.   $x->ble($y);            # true if and only if $x <= $y
  81.   $x->bgt($y);            # true if and only if $x > $y
  82.   $x->bge($y);            # true if and only if $x >= $y
  84.   # Arithmetic methods
  86.   $x->bneg();             # negation
  87.   $x->babs();             # absolute value
  88.   $x->bsgn();             # sign function (-1, 0, 1, or NaN)
  89.   $x->bnorm();            # normalize (no-op)
  90.   $x->binc();             # increment $x by 1
  91.   $x->bdec();             # decrement $x by 1
  92.   $x->badd($y);           # addition (add $y to $x)
  93.   $x->bsub($y);           # subtraction (subtract $y from $x)
  94.   $x->bmul($y);           # multiplication (multiply $x by $y)
  95.   $x->bmuladd($y,$z);     # $x = $x * $y + $z
  96.   $x->bdiv($y);           # division (floored), set $x to quotient
  97.                           # return (quo,rem) or quo if scalar
  98.   $x->btdiv($y);          # division (truncated), set $x to quotient
  99.                           # return (quo,rem) or quo if scalar
  100.   $x->bmod($y);           # modulus (x % y)
  101.   $x->btmod($y);          # modulus (truncated)
  102.   $x->bmodinv($mod);      # modular multiplicative inverse
  103.   $x->bmodpow($y,$mod);   # modular exponentiation (($x ** $y) % $mod)
  104.   $x->bpow($y);           # power of arguments (x ** y)
  105.   $x->blog();             # logarithm of $x to base e (Euler's number)
  106.   $x->blog($base);        # logarithm of $x to base $base (e.g., base 2)
  107.   $x->bexp();             # calculate e ** $x where e is Euler's number
  108.   $x->bnok($y);           # x over y (binomial coefficient n over k)
  109.   $x->bsin();             # sine
  110.   $x->bcos();             # cosine
  111.   $x->batan();            # inverse tangent
  112.   $x->batan2($y);         # two-argument inverse tangent
  113.   $x->bsqrt();            # calculate square-root
  114.   $x->broot($y);          # $y'th root of $x (e.g. $y == 3 => cubic root)
  115.   $x->bfac();             # factorial of $x (1*2*3*4*..$x)
  117.   $x->blsft($n);          # left shift $n places in base 2
  118.   $x->blsft($n,$b);       # left shift $n places in base $b
  119.                           # returns (quo,rem) or quo (scalar context)
  120.   $x->brsft($n);          # right shift $n places in base 2
  121.   $x->brsft($n,$b);       # right shift $n places in base $b
  122.                           # returns (quo,rem) or quo (scalar context)
  124.   # Bitwise methods
  126.   $x->band($y);           # bitwise and
  127.   $x->bior($y);           # bitwise inclusive or
  128.   $x->bxor($y);           # bitwise exclusive or
  129.   $x->bnot();             # bitwise not (two's complement)
  131.   # Rounding methods
  132.   $x->round($A,$P,$mode); # round to accuracy or precision using
  133.                           # rounding mode $mode
  134.   $x->bround($n);         # accuracy: preserve $n digits
  135.   $x->bfround($n);        # $n > 0: round to $nth digit left of dec. point
  136.                           # $n < 0: round to $nth digit right of dec. point
  137.   $x->bfloor();           # round towards minus infinity
  138.   $x->bceil();            # round towards plus infinity
  139.   $x->bint();             # round towards zero
  141.   # Other mathematical methods
  143.   $x->bgcd($y);            # greatest common divisor
  144.   $x->blcm($y);            # least common multiple
  146.   # Object property methods (do not modify the invocand)
  148.   $x->sign();              # the sign, either +, - or NaN
  149.   $x->digit($n);           # the nth digit, counting from the right
  150.   $x->digit(-$n);          # the nth digit, counting from the left
  151.   $x->length();            # return number of digits in number
  152.   ($xl,$f) = $x->length(); # length of number and length of fraction
  153.                            # part, latter is always 0 digits long
  154.                            # for Math::BigInt objects
  155.   $x->mantissa();          # return (signed) mantissa as a Math::BigInt
  156.   $x->exponent();          # return exponent as a Math::BigInt
  157.   $x->parts();             # return (mantissa,exponent) as a Math::BigInt
  158.   $x->sparts();            # mantissa and exponent (as integers)
  159.   $x->nparts();            # mantissa and exponent (normalised)
  160.   $x->eparts();            # mantissa and exponent (engineering notation)
  161.   $x->dparts();            # integer and fraction part
  163.   # Conversion methods (do not modify the invocand)
  165.   $x->bstr();         # decimal notation, possibly zero padded
  166.   $x->bsstr();        # string in scientific notation with integers
  167.   $x->bnstr();        # string in normalized notation
  168.   $x->bestr();        # string in engineering notation
  169.   $x->bdstr();        # string in decimal notation
  170.   $x->as_hex();       # as signed hexadecimal string with prefixed 0x
  171.   $x->as_bin();       # as signed binary string with prefixed 0b
  172.   $x->as_oct();       # as signed octal string with prefixed 0
  173.   $x->as_bytes();     # as byte string
  175.   # Other conversion methods
  177.   $x->numify();           # return as scalar (might overflow or underflow)

DESCRIPTION

Math::BigInt provides support for arbitrary precision integers. Overloading is also provided for Perl operators.

Input

Input values to these routines may be any scalar number or string that looks like a number and represents an integer.

  • Leading and trailing whitespace is ignored.

  • Leading and trailing zeros are ignored.

  • If the string has a "0x" prefix, it is interpreted as a hexadecimal number.

  • If the string has a "0b" prefix, it is interpreted as a binary number.

  • One underline is allowed between any two digits.

  • If the string can not be interpreted, NaN is returned.

Octal numbers are typically prefixed by "0", but since leading zeros are stripped, these methods can not automatically recognize octal numbers, so use the constructor from_oct() to interpret octal strings.

Some examples of valid string input

  1.     Input string                Resulting value
  2.     123                         123
  3.     1.23e2                      123
  4.     12300e-2                    123
  5.     0xcafe                      51966
  6.     0b1101                      13
  7.     67_538_754                  67538754
  8.     -4_5_6.7_8_9e+0_1_0         -4567890000000

Input given as scalar numbers might lose precision. Quote your input to ensure that no digits are lost:

  1.     $x = Math::BigInt->new( 56789012345678901234 );   # bad
  2.     $x = Math::BigInt->new('56789012345678901234');   # good

Currently, Math::BigInt->new() defaults to 0, while Math::BigInt->new('') results in 'NaN'. This might change in the future, so use always the following explicit forms to get a zero or NaN:

  1.     $zero = Math::BigInt->bzero();
  2.     $nan  = Math::BigInt->bnan();

Output

Output values are usually Math::BigInt objects.

Boolean operators is_zero() , is_one() , is_inf() , etc. return true or false.

Comparison operators bcmp() and bacmp() ) return -1, 0, 1, or undef.

METHODS

Configuration methods

Each of the methods below (except config(), accuracy() and precision()) accepts three additional parameters. These arguments $A , $P and $R are accuracy , precision and round_mode . Please see the section about ACCURACY and PRECISION for more information.

Setting a class variable effects all object instance that are created afterwards.

  • accuracy() 
    1.     Math::BigInt->accuracy(5);      # set class accuracy
    2.     $x->accuracy(5);                # set instance accuracy
    4.     $A = Math::BigInt->accuracy();  # get class accuracy
    5.     $A = $x->accuracy();            # get instance accuracy

    Set or get the accuracy, i.e., the number of significant digits. The accuracy must be an integer. If the accuracy is set to undef, no rounding is done.

    Alternatively, one can round the results explicitly using one of round(), bround() or bfround() or by passing the desired accuracy to the method as an additional parameter:

    1.     my $x = Math::BigInt->new(30000);
    2.     my $y = Math::BigInt->new(7);
    3.     print scalar $x->copy()->bdiv($y, 2);               # prints 4300
    4.     print scalar $x->copy()->bdiv($y)->bround(2);       # prints 4300

    Please see the section about ACCURACY and PRECISION for further details.

    1.     $y = Math::BigInt->new(1234567);    # $y is not rounded
    2.     Math::BigInt->accuracy(4);          # set class accuracy to 4
    3.     $x = Math::BigInt->new(1234567);    # $x is rounded automatically
    4.     print "$x $y";                      # prints "1235000 1234567"
    6.     print $x->accuracy();       # prints "4"
    7.     print $y->accuracy();       # also prints "4", since
    8.                                 #   class accuracy is 4
    10.     Math::BigInt->accuracy(5);  # set class accuracy to 5
    11.     print $x->accuracy();       # prints "4", since instance
    12.                                 #   accuracy is 4
    13.     print $y->accuracy();       # prints "5", since no instance
    14.                                 #   accuracy, and class accuracy is 5

    Note: Each class has it's own globals separated from Math::BigInt, but it is possible to subclass Math::BigInt and make the globals of the subclass aliases to the ones from Math::BigInt.

  • precision() 
    1.     Math::BigInt->precision(-2);     # set class precision
    2.     $x->precision(-2);               # set instance precision
    4.     $P = Math::BigInt->precision();  # get class precision
    5.     $P = $x->precision();            # get instance precision

    Set or get the precision, i.e., the place to round relative to the decimal point. The precision must be a integer. Setting the precision to $P means that each number is rounded up or down, depending on the rounding mode, to the nearest multiple of 10**$P. If the precision is set to undef, no rounding is done.

    You might want to use accuracy() instead. With accuracy() you set the number of digits each result should have, with precision() you set the place where to round.

    Please see the section about ACCURACY and PRECISION for further details.

    1.     $y = Math::BigInt->new(1234567);    # $y is not rounded
    2.     Math::BigInt->precision(4);         # set class precision to 4
    3.     $x = Math::BigInt->new(1234567);    # $x is rounded automatically
    4.     print $x;                           # prints "1230000"

    Note: Each class has its own globals separated from Math::BigInt, but it is possible to subclass Math::BigInt and make the globals of the subclass aliases to the ones from Math::BigInt.

  • div_scale()

    Set/get the fallback accuracy. This is the accuracy used when neither accuracy nor precision is set explicitly. It is used when a computation might otherwise attempt to return an infinite number of digits.

  • round_mode()

    Set/get the rounding mode.

  • upgrade()

    Set/get the class for upgrading. When a computation might result in a non-integer, the operands are upgraded to this class. This is used for instance by bignum. The default is undef, thus the following operation creates a Math::BigInt, not a Math::BigFloat:

    1.     my $i = Math::BigInt->new(123);
    2.     my $f = Math::BigFloat->new('123.1');
    4.     print $i + $f, "\n";                # prints 246
  • downgrade()

    Set/get the class for downgrading. The default is undef. Downgrading is not done by Math::BigInt.

  • modify() 
    1.     $x->modify('bpowd');

    This method returns 0 if the object can be modified with the given operation, or 1 if not.

    This is used for instance by Math::BigInt::Constant.

  • config() 
    1.     use Data::Dumper;
    3.     print Dumper ( Math::BigInt->config() );
    4.     print Math::BigInt->config()->{lib},"\n";
    5.     print Math::BigInt->config('lib')},"\n";

    Returns a hash containing the configuration, e.g. the version number, lib loaded etc. The following hash keys are currently filled in with the appropriate information.

    1.     key           Description
    2.                   Example
    3.     ============================================================
    4.     lib           Name of the low-level math library
    5.                   Math::BigInt::Calc
    6.     lib_version   Version of low-level math library (see 'lib')
    7.                   0.30
    8.     class         The class name of config() you just called
    9.                   Math::BigInt
    10.     upgrade       To which class math operations might be
    11.                   upgraded Math::BigFloat
    12.     downgrade     To which class math operations might be
    13.                   downgraded undef
    14.     precision     Global precision
    15.                   undef
    16.     accuracy      Global accuracy
    17.                   undef
    18.     round_mode    Global round mode
    19.                   even
    20.     version       version number of the class you used
    21.                   1.61
    22.     div_scale     Fallback accuracy for div
    23.                   40
    24.     trap_nan      If true, traps creation of NaN via croak()
    25.                   1
    26.     trap_inf      If true, traps creation of +inf/-inf via croak()
    27.                                     1

    The following values can be set by passing config() a reference to a hash:

    1.         accuracy precision round_mode div_scale
    2.         upgrade downgrade trap_inf trap_nan

    Example:

    1.     $new_cfg = Math::BigInt->config(
    2.         { trap_inf => 1, precision => 5 }
    3.     );

Constructor methods

  • new() 
    1.     $x = Math::BigInt->new($str,$A,$P,$R);

    Creates a new Math::BigInt object from a scalar or another Math::BigInt object. The input is accepted as decimal, hexadecimal (with leading '0x') or binary (with leading '0b').

    See Input for more info on accepted input formats.

  • from_hex() 
    1.     $x = Math::BigInt->from_hex("0xcafe");    # input is hexadecimal

    Interpret input as a hexadecimal string. A "0x" or "x" prefix is optional. A single underscore character may be placed right after the prefix, if present, or between any two digits. If the input is invalid, a NaN is returned.

  • from_oct() 
    1.     $x = Math::BigInt->from_oct("0775");      # input is octal

    Interpret the input as an octal string and return the corresponding value. A "0" (zero) prefix is optional. A single underscore character may be placed right after the prefix, if present, or between any two digits. If the input is invalid, a NaN is returned.

  • from_bin() 
    1.     $x = Math::BigInt->from_bin("0b10011");   # input is binary

    Interpret the input as a binary string. A "0b" or "b" prefix is optional. A single underscore character may be placed right after the prefix, if present, or between any two digits. If the input is invalid, a NaN is returned.

  • from_bytes() 
    1.     $x = Math::BigInt->from_bytes("\xf3\x6b");  # $x = 62315

    Interpret the input as a byte string, assuming big endian byte order. The output is always a non-negative, finite integer.

    In some special cases, from_bytes() matches the conversion done by unpack():

    1.     $b = "\x4e";                             # one char byte string
    2.     $x = Math::BigInt->from_bytes($b);       # = 78
    3.     $y = unpack "C", $b;                     # ditto, but scalar
    5.     $b = "\xf3\x6b";                         # two char byte string
    6.     $x = Math::BigInt->from_bytes($b);       # = 62315
    7.     $y = unpack "S>", $b;                    # ditto, but scalar
    9.     $b = "\x2d\xe0\x49\xad";                 # four char byte string
    10.     $x = Math::BigInt->from_bytes($b);       # = 769673645
    11.     $y = unpack "L>", $b;                    # ditto, but scalar
    13.     $b = "\x2d\xe0\x49\xad\x2d\xe0\x49\xad"; # eight char byte string
    14.     $x = Math::BigInt->from_bytes($b);       # = 3305723134637787565
    15.     $y = unpack "Q>", $b;                    # ditto, but scalar
  • bzero() 
    1.     $x = Math::BigInt->bzero();
    2.     $x->bzero();

    Returns a new Math::BigInt object representing zero. If used as an instance method, assigns the value to the invocand.

  • bone() 
    1.     $x = Math::BigInt->bone();          # +1
    2.     $x = Math::BigInt->bone("+");       # +1
    3.     $x = Math::BigInt->bone("-");       # -1
    4.     $x->bone();                         # +1
    5.     $x->bone("+");                      # +1
    6.     $x->bone('-');                      # -1

    Creates a new Math::BigInt object representing one. The optional argument is either '-' or '+', indicating whether you want plus one or minus one. If used as an instance method, assigns the value to the invocand.

  • binf() 
    1.     $x = Math::BigInt->binf($sign);

    Creates a new Math::BigInt object representing infinity. The optional argument is either '-' or '+', indicating whether you want infinity or minus infinity. If used as an instance method, assigns the value to the invocand.

    1.     $x->binf();
    2.     $x->binf('-');
  • bnan() 
    1.     $x = Math::BigInt->bnan();

    Creates a new Math::BigInt object representing NaN (Not A Number). If used as an instance method, assigns the value to the invocand.

    1.     $x->bnan();
  • bpi() 
    1.     $x = Math::BigInt->bpi(100);        # 3
    2.     $x->bpi(100);                       # 3

    Creates a new Math::BigInt object representing PI. If used as an instance method, assigns the value to the invocand. With Math::BigInt this always returns 3.

    If upgrading is in effect, returns PI, rounded to N digits with the current rounding mode:

    1.     use Math::BigFloat;
    2.     use Math::BigInt upgrade => "Math::BigFloat";
    3.     print Math::BigInt->bpi(3), "\n";           # 3.14
    4.     print Math::BigInt->bpi(100), "\n";         # 3.1415....
  • copy() 
    1.     $x->copy();         # make a true copy of $x (unlike $y = $x)
  • as_int()
  • as_number()

    These methods are called when Math::BigInt encounters an object it doesn't know how to handle. For instance, assume $x is a Math::BigInt, or subclass thereof, and $y is defined, but not a Math::BigInt, or subclass thereof. If you do

    1.     $x -> badd($y);

    $y needs to be converted into an object that $x can deal with. This is done by first checking if $y is something that $x might be upgraded to. If that is the case, no further attempts are made. The next is to see if $y supports the method as_int() . If it does, as_int() is called, but if it doesn't, the next thing is to see if $y supports the method as_number() . If it does, as_number() is called. The method as_int() (and as_number() ) is expected to return either an object that has the same class as $x, a subclass thereof, or a string that ref($x)->new() can parse to create an object.

    as_number() is an alias to as_int() . as_number was introduced in v1.22, while as_int() was introduced in v1.68.

    In Math::BigInt, as_int() has the same effect as copy() .

Boolean methods

None of these methods modify the invocand object.

  • is_zero() 
    1.     $x->is_zero();              # true if $x is 0

    Returns true if the invocand is zero and false otherwise.

  • is_one( [ SIGN ]) 
    1.     $x->is_one();               # true if $x is +1
    2.     $x->is_one("+");            # ditto
    3.     $x->is_one("-");            # true if $x is -1

    Returns true if the invocand is one and false otherwise.

  • is_finite() 
    1.     $x->is_finite();    # true if $x is not +inf, -inf or NaN

    Returns true if the invocand is a finite number, i.e., it is neither +inf, -inf, nor NaN.

  • is_inf( [ SIGN ] ) 
    1.     $x->is_inf();               # true if $x is +inf
    2.     $x->is_inf("+");            # ditto
    3.     $x->is_inf("-");            # true if $x is -inf

    Returns true if the invocand is infinite and false otherwise.

  • is_nan() 
    1.     $x->is_nan();               # true if $x is NaN
  • is_positive()
  • is_pos() 
    1.     $x->is_positive();          # true if > 0
    2.     $x->is_pos();               # ditto

    Returns true if the invocand is positive and false otherwise. A NaN is neither positive nor negative.

  • is_negative()
  • is_neg() 
    1.     $x->is_negative();          # true if < 0
    2.     $x->is_neg();               # ditto

    Returns true if the invocand is negative and false otherwise. A NaN is neither positive nor negative.

  • is_odd() 
    1.     $x->is_odd();               # true if odd, false for even

    Returns true if the invocand is odd and false otherwise. NaN , +inf , and -inf are neither odd nor even.

  • is_even() 
    1.     $x->is_even();              # true if $x is even

    Returns true if the invocand is even and false otherwise. NaN , +inf , -inf are not integers and are neither odd nor even.

  • is_int() 
    1.     $x->is_int();               # true if $x is an integer

    Returns true if the invocand is an integer and false otherwise. NaN , +inf , -inf are not integers.

Comparison methods

None of these methods modify the invocand object. Note that a NaN is neither less than, greater than, or equal to anything else, even a NaN .

  • bcmp() 
    1.     $x->bcmp($y);

    Returns -1, 0, 1 depending on whether $x is less than, equal to, or grater than $y. Returns undef if any operand is a NaN.

  • bacmp() 
    1.     $x->bacmp($y);

    Returns -1, 0, 1 depending on whether the absolute value of $x is less than, equal to, or grater than the absolute value of $y. Returns undef if any operand is a NaN.

  • beq() 
    1.     $x -> beq($y);

    Returns true if and only if $x is equal to $y, and false otherwise.

  • bne() 
    1.     $x -> bne($y);

    Returns true if and only if $x is not equal to $y, and false otherwise.

  • blt() 
    1.     $x -> blt($y);

    Returns true if and only if $x is equal to $y, and false otherwise.

  • ble() 
    1.     $x -> ble($y);

    Returns true if and only if $x is less than or equal to $y, and false otherwise.

  • bgt() 
    1.     $x -> bgt($y);

    Returns true if and only if $x is greater than $y, and false otherwise.

  • bge() 
    1.     $x -> bge($y);

    Returns true if and only if $x is greater than or equal to $y, and false otherwise.

Arithmetic methods

These methods modify the invocand object and returns it.

  • bneg() 
    1.     $x->bneg();

    Negate the number, e.g. change the sign between '+' and '-', or between '+inf' and '-inf', respectively. Does nothing for NaN or zero.

  • babs() 
    1.     $x->babs();

    Set the number to its absolute value, e.g. change the sign from '-' to '+' and from '-inf' to '+inf', respectively. Does nothing for NaN or positive numbers.

  • bsgn() 
    1.     $x->bsgn();

    Signum function. Set the number to -1, 0, or 1, depending on whether the number is negative, zero, or positive, respectively. Does not modify NaNs.

  • bnorm() 
    1.     $x->bnorm();                        # normalize (no-op)

    Normalize the number. This is a no-op and is provided only for backwards compatibility.

  • binc() 
    1.     $x->binc();                 # increment x by 1
  • bdec() 
    1.     $x->bdec();                 # decrement x by 1
  • badd() 
    1.     $x->badd($y);               # addition (add $y to $x)
  • bsub() 
    1.     $x->bsub($y);               # subtraction (subtract $y from $x)
  • bmul() 
    1.     $x->bmul($y);               # multiplication (multiply $x by $y)
  • bmuladd() 
    1.     $x->bmuladd($y,$z);

    Multiply $x by $y, and then add $z to the result,

    This method was added in v1.87 of Math::BigInt (June 2007).

  • bdiv() 
    1.     $x->bdiv($y);               # divide, set $x to quotient

    Divides $x by $y by doing floored division (F-division), where the quotient is the floored (rounded towards negative infinity) quotient of the two operands. In list context, returns the quotient and the remainder. The remainder is either zero or has the same sign as the second operand. In scalar context, only the quotient is returned.

    The quotient is always the greatest integer less than or equal to the real-valued quotient of the two operands, and the remainder (when it is non-zero) always has the same sign as the second operand; so, for example,

    1.       1 /  4  => ( 0,  1)
    2.       1 / -4  => (-1, -3)
    3.      -3 /  4  => (-1,  1)
    4.      -3 / -4  => ( 0, -3)
    5.     -11 /  2  => (-5,  1)
    6.      11 / -2  => (-5, -1)

    The behavior of the overloaded operator % agrees with the behavior of Perl's built-in % operator (as documented in the perlop manpage), and the equation

    1.     $x == ($x / $y) * $y + ($x % $y)

    holds true for any finite $x and finite, non-zero $y.

    Perl's "use integer" might change the behaviour of % and / for scalars. This is because under 'use integer' Perl does what the underlying C library thinks is right, and this varies. However, "use integer" does not change the way things are done with Math::BigInt objects.

  • btdiv() 
    1.     $x->btdiv($y);              # divide, set $x to quotient

    Divides $x by $y by doing truncated division (T-division), where quotient is the truncated (rouneded towards zero) quotient of the two operands. In list context, returns the quotient and the remainder. The remainder is either zero or has the same sign as the first operand. In scalar context, only the quotient is returned.

  • bmod() 
    1.     $x->bmod($y);               # modulus (x % y)

    Returns $x modulo $y, i.e., the remainder after floored division (F-division). This method is like Perl's % operator. See bdiv().

  • btmod() 
    1.     $x->btmod($y);              # modulus

    Returns the remainer after truncated division (T-division). See btdiv().

  • bmodinv() 
    1.     $x->bmodinv($mod);          # modular multiplicative inverse

    Returns the multiplicative inverse of $x modulo $mod . If

    1.     $y = $x -> copy() -> bmodinv($mod)

    then $y is the number closest to zero, and with the same sign as $mod , satisfying

    1.     ($x * $y) % $mod = 1 % $mod

    If $x and $y are non-zero, they must be relative primes, i.e., bgcd($y, $mod)==1 . 'NaN ' is returned when no modular multiplicative inverse exists.

  • bmodpow() 
    1.     $num->bmodpow($exp,$mod);           # modular exponentiation
    2.                                         # ($num**$exp % $mod)

    Returns the value of $num taken to the power $exp in the modulus $mod using binary exponentiation. bmodpow is far superior to writing

    1.     $num ** $exp % $mod

    because it is much faster - it reduces internal variables into the modulus whenever possible, so it operates on smaller numbers.

    bmodpow also supports negative exponents.

    1.     bmodpow($num, -1, $mod)

    is exactly equivalent to

    1.     bmodinv($num, $mod)
  • bpow() 
    1.     $x->bpow($y);               # power of arguments (x ** y)

    bpow() (and the rounding functions) now modifies the first argument and returns it, unlike the old code which left it alone and only returned the result. This is to be consistent with badd() etc. The first three modifies $x, the last one won't:

    1.     print bpow($x,$i),"\n";         # modify $x
    2.     print $x->bpow($i),"\n";        # ditto
    3.     print $x **= $i,"\n";           # the same
    4.     print $x ** $i,"\n";            # leave $x alone

    The form $x **= $y is faster than $x = $x ** $y; , though.

  • blog() 
    1.     $x->blog($base, $accuracy);         # logarithm of x to the base $base

    If $base is not defined, Euler's number (e) is used:

    1.     print $x->blog(undef, 100);         # log(x) to 100 digits
  • bexp() 
    1.     $x->bexp($accuracy);                # calculate e ** X

    Calculates the expression e ** $x where e is Euler's number.

    This method was added in v1.82 of Math::BigInt (April 2007).

    See also blog().

  • bnok() 
    1.     $x->bnok($y);               # x over y (binomial coefficient n over k)

    Calculates the binomial coefficient n over k, also called the "choose" function. The result is equivalent to:

    1.     ( n )      n!
    2.     | - |  = -------
    3.     ( k )    k!(n-k)!

    This method was added in v1.84 of Math::BigInt (April 2007).

  • bsin() 
    1.     my $x = Math::BigInt->new(1);
    2.     print $x->bsin(100), "\n";

    Calculate the sine of $x, modifying $x in place.

    In Math::BigInt, unless upgrading is in effect, the result is truncated to an integer.

    This method was added in v1.87 of Math::BigInt (June 2007).

  • bcos() 
    1.     my $x = Math::BigInt->new(1);
    2.     print $x->bcos(100), "\n";

    Calculate the cosine of $x, modifying $x in place.

    In Math::BigInt, unless upgrading is in effect, the result is truncated to an integer.

    This method was added in v1.87 of Math::BigInt (June 2007).

  • batan() 
    1.     my $x = Math::BigFloat->new(0.5);
    2.     print $x->batan(100), "\n";

    Calculate the arcus tangens of $x, modifying $x in place.

    In Math::BigInt, unless upgrading is in effect, the result is truncated to an integer.

    This method was added in v1.87 of Math::BigInt (June 2007).

  • batan2() 
    1.     my $x = Math::BigInt->new(1);
    2.     my $y = Math::BigInt->new(1);
    3.     print $y->batan2($x), "\n";

    Calculate the arcus tangens of $y divided by $x , modifying $y in place.

    In Math::BigInt, unless upgrading is in effect, the result is truncated to an integer.

    This method was added in v1.87 of Math::BigInt (June 2007).

  • bsqrt() 
    1.     $x->bsqrt();                # calculate square-root

    bsqrt() returns the square root truncated to an integer.

    If you want a better approximation of the square root, then use:

    1.     $x = Math::BigFloat->new(12);
    2.     Math::BigFloat->precision(0);
    3.     Math::BigFloat->round_mode('even');
    4.     print $x->copy->bsqrt(),"\n";           # 4
    6.     Math::BigFloat->precision(2);
    7.     print $x->bsqrt(),"\n";                 # 3.46
    8.     print $x->bsqrt(3),"\n";                # 3.464
  • broot() 
    1.     $x->broot($N);

    Calculates the N'th root of $x .

  • bfac() 
    1.     $x->bfac();                 # factorial of $x (1*2*3*4*..*$x)
  • brsft() 
    1.     $x->brsft($n);              # right shift $n places in base 2
    2.     $x->brsft($n, $b);          # right shift $n places in base $b

    The latter is equivalent to

    1.     $x -> bdiv($b -> copy() -> bpow($n))
  • blsft() 
    1.     $x->blsft($n);              # left shift $n places in base 2
    2.     $x->blsft($n, $b);          # left shift $n places in base $b

    The latter is equivalent to

    1.     $x -> bmul($b -> copy() -> bpow($n))

Bitwise methods

  • band() 
    1.     $x->band($y);               # bitwise and
  • bior() 
    1.     $x->bior($y);               # bitwise inclusive or
  • bxor() 
    1.     $x->bxor($y);               # bitwise exclusive or
  • bnot() 
    1.     $x->bnot();                 # bitwise not (two's complement)

    Two's complement (bitwise not). This is equivalent to, but faster than,

    1.     $x->binc()->bneg();

Rounding methods

  • round() 
    1.     $x->round($A,$P,$round_mode);

    Round $x to accuracy $A or precision $P using the round mode $round_mode .

  • bround() 
    1.     $x->bround($N);               # accuracy: preserve $N digits

    Rounds $x to an accuracy of $N digits.

  • bfround() 
    1.     $x->bfround($N);

    Rounds to a multiple of 10**$N. Examples:

    1.     Input            N          Result
    3.     123456.123456    3          123500
    4.     123456.123456    2          123450
    5.     123456.123456   -2          123456.12
    6.     123456.123456   -3          123456.123
  • bfloor() 
    1.     $x->bfloor();

    Round $x towards minus infinity, i.e., set $x to the largest integer less than or equal to $x.

  • bceil() 
    1.     $x->bceil();

    Round $x towards plus infinity, i.e., set $x to the smallest integer greater than or equal to $x).

  • bint() 
    1.     $x->bint();

    Round $x towards zero.

Other mathematical methods

  • bgcd() 
    1.     $x -> bgcd($y);             # GCD of $x and $y
    2.     $x -> bgcd($y, $z, ...);    # GCD of $x, $y, $z, ...

    Returns the greatest common divisor (GCD).

  • blcm() 
    1.     $x -> blcm($y);             # LCM of $x and $y
    2.     $x -> blcm($y, $z, ...);    # LCM of $x, $y, $z, ...

    Returns the least common multiple (LCM).

Object property methods

  • sign() 
    1.     $x->sign();

    Return the sign, of $x, meaning either + , - , -inf , +inf or NaN.

    If you want $x to have a certain sign, use one of the following methods:

    1.     $x->babs();                 # '+'
    2.     $x->babs()->bneg();         # '-'
    3.     $x->bnan();                 # 'NaN'
    4.     $x->binf();                 # '+inf'
    5.     $x->binf('-');              # '-inf'
  • digit() 
    1.     $x->digit($n);       # return the nth digit, counting from right

    If $n is negative, returns the digit counting from left.

  • length() 
    1.     $x->length();
    2.     ($xl, $fl) = $x->length();

    Returns the number of digits in the decimal representation of the number. In list context, returns the length of the integer and fraction part. For Math::BigInt objects, the length of the fraction part is always 0.

    The following probably doesn't do what you expect:

    1.     $c = Math::BigInt->new(123);
    2.     print $c->length(),"\n";                # prints 30

    It prints both the number of digits in the number and in the fraction part since print calls length() in list context. Use something like:

    1.     print scalar $c->length(),"\n";         # prints 3
  • mantissa() 
    1.     $x->mantissa();

    Return the signed mantissa of $x as a Math::BigInt.

  • exponent() 
    1.     $x->exponent();

    Return the exponent of $x as a Math::BigInt.

  • parts() 
    1.     $x->parts();

    Returns the significand (mantissa) and the exponent as integers. In Math::BigFloat, both are returned as Math::BigInt objects.

  • sparts()

    Returns the significand (mantissa) and the exponent as integers. In scalar context, only the significand is returned. The significand is the integer with the smallest absolute value. The output of sparts() corresponds to the output from bsstr() .

    In Math::BigInt, this method is identical to parts() .

  • nparts()

    Returns the significand (mantissa) and exponent corresponding to normalized notation. In scalar context, only the significand is returned. For finite non-zero numbers, the significand's absolute value is greater than or equal to 1 and less than 10. The output of nparts() corresponds to the output from bnstr() . In Math::BigInt, if the significand can not be represented as an integer, upgrading is performed or NaN is returned.

  • eparts()

    Returns the significand (mantissa) and exponent corresponding to engineering notation. In scalar context, only the significand is returned. For finite non-zero numbers, the significand's absolute value is greater than or equal to 1 and less than 1000, and the exponent is a multiple of 3. The output of eparts() corresponds to the output from bestr() . In Math::BigInt, if the significand can not be represented as an integer, upgrading is performed or NaN is returned.

  • dparts()

    Returns the integer part and the fraction part. If the fraction part can not be represented as an integer, upgrading is performed or NaN is returned. The output of dparts() corresponds to the output from bdstr() .

String conversion methods

  • bstr()

    Returns a string representing the number using decimal notation. In Math::BigFloat, the output is zero padded according to the current accuracy or precision, if any of those are defined.

  • bsstr()

    Returns a string representing the number using scientific notation where both the significand (mantissa) and the exponent are integers. The output corresponds to the output from sparts() .

    1.       123 is returned as "123e+0"
    2.      1230 is returned as "123e+1"
    3.     12300 is returned as "123e+2"
    4.     12000 is returned as "12e+3"
    5.     10000 is returned as "1e+4"
  • bnstr()

    Returns a string representing the number using normalized notation, the most common variant of scientific notation. For finite non-zero numbers, the absolute value of the significand is less than or equal to 1 and less than 10. The output corresponds to the output from nparts() .

    1.       123 is returned as "1.23e+2"
    2.      1230 is returned as "1.23e+3"
    3.     12300 is returned as "1.23e+4"
    4.     12000 is returned as "1.2e+4"
    5.     10000 is returned as "1e+4"
  • bestr()

    Returns a string representing the number using engineering notation. For finite non-zero numbers, the absolute value of the significand is less than or equal to 1 and less than 1000, and the exponent is a multiple of 3. The output corresponds to the output from eparts() .

    1.       123 is returned as "123e+0"
    2.      1230 is returned as "1.23e+3"
    3.     12300 is returned as "12.3e+3"
    4.     12000 is returned as "12e+3"
    5.     10000 is returned as "10e+3"
  • bdstr()

    Returns a string representing the number using decimal notation. The output corresponds to the output from dparts() .

    1.       123 is returned as "123"
    2.      1230 is returned as "1230"
    3.     12300 is returned as "12300"
    4.     12000 is returned as "12000"
    5.     10000 is returned as "10000"
  • as_hex() 
    1.     $x->as_hex();

    Returns a string representing the number using hexadecimal notation. The output is prefixed by "0x".

  • as_bin() 
    1.     $x->as_bin();

    Returns a string representing the number using binary notation. The output is prefixed by "0b".

  • as_oct() 
    1.     $x->as_oct();

    Returns a string representing the number using octal notation. The output is prefixed by "0".

  • as_bytes() 
    1.     $x = Math::BigInt->new("1667327589");
    2.     $s = $x->as_bytes();                    # $s = "cafe"

    Returns a byte string representing the number using big endian byte order. The invocand must be a non-negative, finite integer.

Other conversion methods

  • numify() 
    1.     print $x->numify();

    Returns a Perl scalar from $x. It is used automatically whenever a scalar is needed, for instance in array index operations.

ACCURACY and PRECISION

Math::BigInt and Math::BigFloat have full support for accuracy and precision based rounding, both automatically after every operation, as well as manually.

This section describes the accuracy/precision handling in Math::BigInt and Math::BigFloat as it used to be and as it is now, complete with an explanation of all terms and abbreviations.

Not yet implemented things (but with correct description) are marked with '!', things that need to be answered are marked with '?'.

In the next paragraph follows a short description of terms used here (because these may differ from terms used by others people or documentation).

During the rest of this document, the shortcuts A (for accuracy), P (for precision), F (fallback) and R (rounding mode) are be used.

Precision P

Precision is a fixed number of digits before (positive) or after (negative) the decimal point. For example, 123.45 has a precision of -2. 0 means an integer like 123 (or 120). A precision of 2 means at least two digits to the left of the decimal point are zero, so 123 with P = 1 becomes 120. Note that numbers with zeros before the decimal point may have different precisions, because 1200 can have P = 0, 1 or 2 (depending on what the initial value was). It could also have p < 0, when the digits after the decimal point are zero.

The string output (of floating point numbers) is padded with zeros:

  1.     Initial value    P      A       Result          String
  2.     ------------------------------------------------------------
  3.     1234.01         -3              1000            1000
  4.     1234            -2              1200            1200
  5.     1234.5          -1              1230            1230
  6.     1234.001         1              1234            1234.0
  7.     1234.01          0              1234            1234
  8.     1234.01          2              1234.01         1234.01
  9.     1234.01          5              1234.01         1234.01000

For Math::BigInt objects, no padding occurs.

Accuracy A

Number of significant digits. Leading zeros are not counted. A number may have an accuracy greater than the non-zero digits when there are zeros in it or trailing zeros. For example, 123.456 has A of 6, 10203 has 5, 123.0506 has 7, 123.45000 has 8 and 0.000123 has 3.

The string output (of floating point numbers) is padded with zeros:

  1.     Initial value    P      A       Result          String
  2.     ------------------------------------------------------------
  3.     1234.01                 3       1230            1230
  4.     1234.01                 6       1234.01         1234.01
  5.     1234.1                  8       1234.1          1234.1000

For Math::BigInt objects, no padding occurs.

Fallback F

When both A and P are undefined, this is used as a fallback accuracy when dividing numbers.

Rounding mode R

When rounding a number, different 'styles' or 'kinds' of rounding are possible. (Note that random rounding, as in Math::Round, is not implemented.)

  • 'trunc'

    truncation invariably removes all digits following the rounding place, replacing them with zeros. Thus, 987.65 rounded to tens (P = 1) becomes 980, and rounded to the fourth sigdig becomes 987.6 (A = 4). 123.456 rounded to the second place after the decimal point (P = -2) becomes 123.46.

    All other implemented styles of rounding attempt to round to the "nearest digit." If the digit D immediately to the right of the rounding place (skipping the decimal point) is greater than 5, the number is incremented at the rounding place (possibly causing a cascade of incrementation): e.g. when rounding to units, 0.9 rounds to 1, and -19.9 rounds to -20. If D < 5, the number is similarly truncated at the rounding place: e.g. when rounding to units, 0.4 rounds to 0, and -19.4 rounds to -19.

    However the results of other styles of rounding differ if the digit immediately to the right of the rounding place (skipping the decimal point) is 5 and if there are no digits, or no digits other than 0, after that 5. In such cases:

  • 'even'

    rounds the digit at the rounding place to 0, 2, 4, 6, or 8 if it is not already. E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.

  • 'odd'

    rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if it is not already. E.g., when rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.

  • '+inf'

    round to plus infinity, i.e. always round up. E.g., when rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5, and 0.4501 also becomes 0.5.

  • '-inf'

    round to minus infinity, i.e. always round down. E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.

  • 'zero'

    round to zero, i.e. positive numbers down, negative ones up. E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.5, but 0.4501 becomes 0.5.

  • 'common'

    round up if the digit immediately to the right of the rounding place is 5 or greater, otherwise round down. E.g., 0.15 becomes 0.2 and 0.149 becomes 0.1.

The handling of A & P in MBI/MBF (the old core code shipped with Perl versions <= 5.7.2) is like this:

  • Precision 
    1.   * bfround($p) is able to round to $p number of digits after the decimal
    2.     point
    3.   * otherwise P is unused
  • Accuracy (significant digits) 
    1.   * bround($a) rounds to $a significant digits
    2.   * only bdiv() and bsqrt() take A as (optional) parameter
    3.     + other operations simply create the same number (bneg etc), or
    4.       more (bmul) of digits
    5.     + rounding/truncating is only done when explicitly calling one
    6.       of bround or bfround, and never for Math::BigInt (not implemented)
    7.   * bsqrt() simply hands its accuracy argument over to bdiv.
    8.   * the documentation and the comment in the code indicate two
    9.     different ways on how bdiv() determines the maximum number
    10.     of digits it should calculate, and the actual code does yet
    11.     another thing
    12.     POD:
    13.       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
    14.     Comment:
    15.       result has at most max(scale, length(dividend), length(divisor)) digits
    16.     Actual code:
    17.       scale = max(scale, length(dividend)-1,length(divisor)-1);
    18.       scale += length(divisor) - length(dividend);
    19.     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10
    20.     So for lx = 3, ly = 9, scale = 10, scale will actually be 16
    21.     (10+9-3). Actually, the 'difference' added to the scale is cal-
    22.     culated from the number of "significant digits" in dividend and
    23.     divisor, which is derived by looking at the length of the man-
    24.     tissa. Which is wrong, since it includes the + sign (oops) and
    25.     actually gets 2 for '+100' and 4 for '+101'. Oops again. Thus
    26.     124/3 with div_scale=1 will get you '41.3' based on the strange
    27.     assumption that 124 has 3 significant digits, while 120/7 will
    28.     get you '17', not '17.1' since 120 is thought to have 2 signif-
    29.     icant digits. The rounding after the division then uses the
    30.     remainder and $y to determine whether it must round up or down.
    31.  ?  I have no idea which is the right way. That's why I used a slightly more
    32.   ?  simple scheme and tweaked the few failing testcases to match it.

This is how it works now:

  • Setting/Accessing 
    1.   * You can set the A global via Math::BigInt->accuracy() or
    2.     Math::BigFloat->accuracy() or whatever class you are using.
    3.   * You can also set P globally by using Math::SomeClass->precision()
    4.     likewise.
    5.   * Globals are classwide, and not inherited by subclasses.
    6.   * to undefine A, use Math::SomeCLass->accuracy(undef);
    7.   * to undefine P, use Math::SomeClass->precision(undef);
    8.   * Setting Math::SomeClass->accuracy() clears automatically
    9.     Math::SomeClass->precision(), and vice versa.
    10.   * To be valid, A must be > 0, P can have any value.
    11.   * If P is negative, this means round to the P'th place to the right of the
    12.     decimal point; positive values mean to the left of the decimal point.
    13.     P of 0 means round to integer.
    14.   * to find out the current global A, use Math::SomeClass->accuracy()
    15.   * to find out the current global P, use Math::SomeClass->precision()
    16.   * use $x->accuracy() respective $x->precision() for the local
    17.     setting of $x.
    18.   * Please note that $x->accuracy() respective $x->precision()
    19.     return eventually defined global A or P, when $x's A or P is not
    20.     set.
  • Creating numbers 
    1.   * When you create a number, you can give the desired A or P via:
    2.     $x = Math::BigInt->new($number,$A,$P);
    3.   * Only one of A or P can be defined, otherwise the result is NaN
    4.   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
    5.     globals (if set) will be used. Thus changing the global defaults later on
    6.     will not change the A or P of previously created numbers (i.e., A and P of
    7.     $x will be what was in effect when $x was created)
    8.   * If given undef for A and P, NO rounding will occur, and the globals will
    9.     NOT be used. This is used by subclasses to create numbers without
    10.     suffering rounding in the parent. Thus a subclass is able to have its own
    11.     globals enforced upon creation of a number by using
    12.     $x = Math::BigInt->new($number,undef,undef):
    14.         use Math::BigInt::SomeSubclass;
    15.         use Math::BigInt;
    17.         Math::BigInt->accuracy(2);
    18.         Math::BigInt::SomeSubClass->accuracy(3);
    19.         $x = Math::BigInt::SomeSubClass->new(1234);
    21.     $x is now 1230, and not 1200. A subclass might choose to implement
    22.     this otherwise, e.g. falling back to the parent's A and P.
  • Usage 
    1.   * If A or P are enabled/defined, they are used to round the result of each
    2.     operation according to the rules below
    3.   * Negative P is ignored in Math::BigInt, since Math::BigInt objects never
    4.     have digits after the decimal point
    5.   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
    6.     Math::BigInt as globals does not tamper with the parts of a Math::BigFloat.
    7.     A flag is used to mark all Math::BigFloat numbers as 'never round'.
  • Precedence 
    1.   * It only makes sense that a number has only one of A or P at a time.
    2.     If you set either A or P on one object, or globally, the other one will
    3.     be automatically cleared.
    4.   * If two objects are involved in an operation, and one of them has A in
    5.     effect, and the other P, this results in an error (NaN).
    6.   * A takes precedence over P (Hint: A comes before P).
    7.     If neither of them is defined, nothing is used, i.e. the result will have
    8.     as many digits as it can (with an exception for bdiv/bsqrt) and will not
    9.     be rounded.
    10.   * There is another setting for bdiv() (and thus for bsqrt()). If neither of
    11.     A or P is defined, bdiv() will use a fallback (F) of $div_scale digits.
    12.     If either the dividend's or the divisor's mantissa has more digits than
    13.     the value of F, the higher value will be used instead of F.
    14.     This is to limit the digits (A) of the result (just consider what would
    15.     happen with unlimited A and P in the case of 1/3 :-)
    16.   * bdiv will calculate (at least) 4 more digits than required (determined by
    17.     A, P or F), and, if F is not used, round the result
    18.     (this will still fail in the case of a result like 0.12345000000001 with A
    19.     or P of 5, but this can not be helped - or can it?)
    20.   * Thus you can have the math done by on Math::Big* class in two modi:
    21.     + never round (this is the default):
    22.       This is done by setting A and P to undef. No math operation
    23.       will round the result, with bdiv() and bsqrt() as exceptions to guard
    24.       against overflows. You must explicitly call bround(), bfround() or
    25.       round() (the latter with parameters).
    26.       Note: Once you have rounded a number, the settings will 'stick' on it
    27.       and 'infect' all other numbers engaged in math operations with it, since
    28.       local settings have the highest precedence. So, to get SaferRound[tm],
    29.       use a copy() before rounding like this:
    31.         $x = Math::BigFloat->new(12.34);
    32.         $y = Math::BigFloat->new(98.76);
    33.         $z = $x * $y;                           # 1218.6984
    34.         print $x->copy()->bround(3);            # 12.3 (but A is now 3!)
    35.         $z = $x * $y;                           # still 1218.6984, without
    36.                                                 # copy would have been 1210!
    38.     + round after each op:
    39.       After each single operation (except for testing like is_zero()), the
    40.       method round() is called and the result is rounded appropriately. By
    41.       setting proper values for A and P, you can have all-the-same-A or
    42.       all-the-same-P modes. For example, Math::Currency might set A to undef,
    43.       and P to -2, globally.
    45.  ?Maybe an extra option that forbids local A & P settings would be in order,
    46.   ?so that intermediate rounding does not 'poison' further math?
  • Overriding globals 
    1.   * you will be able to give A, P and R as an argument to all the calculation
    2.     routines; the second parameter is A, the third one is P, and the fourth is
    3.     R (shift right by one for binary operations like badd). P is used only if
    4.     the first parameter (A) is undefined. These three parameters override the
    5.     globals in the order detailed as follows, i.e. the first defined value
    6.     wins:
    7.     (local: per object, global: global default, parameter: argument to sub)
    8.       + parameter A
    9.       + parameter P
    10.       + local A (if defined on both of the operands: smaller one is taken)
    11.       + local P (if defined on both of the operands: bigger one is taken)
    12.       + global A
    13.       + global P
    14.       + global F
    15.   * bsqrt() will hand its arguments to bdiv(), as it used to, only now for two
    16.     arguments (A and P) instead of one
  • Local settings 
    1.   * You can set A or P locally by using $x->accuracy() or
    2.     $x->precision()
    3.     and thus force different A and P for different objects/numbers.
    4.   * Setting A or P this way immediately rounds $x to the new value.
    5.   * $x->accuracy() clears $x->precision(), and vice versa.
  • Rounding 
    1.   * the rounding routines will use the respective global or local settings.
    2.     bround() is for accuracy rounding, while bfround() is for precision
    3.   * the two rounding functions take as the second parameter one of the
    4.     following rounding modes (R):
    5.     'even', 'odd', '+inf', '-inf', 'zero', 'trunc', 'common'
    6.   * you can set/get the global R by using Math::SomeClass->round_mode()
    7.     or by setting $Math::SomeClass::round_mode
    8.   * after each operation, $result->round() is called, and the result may
    9.     eventually be rounded (that is, if A or P were set either locally,
    10.     globally or as parameter to the operation)
    11.   * to manually round a number, call $x->round($A,$P,$round_mode);
    12.     this will round the number by using the appropriate rounding function
    13.     and then normalize it.
    14.   * rounding modifies the local settings of the number:
    16.         $x = Math::BigFloat->new(123.456);
    17.         $x->accuracy(5);
    18.         $x->bround(4);
    20.     Here 4 takes precedence over 5, so 123.5 is the result and $x->accuracy()
    21.     will be 4 from now on.
  • Default values 
    1.   * R: 'even'
    2.   * F: 40
    3.   * A: undef
    4.   * P: undef
  • Remarks 
    1.   * The defaults are set up so that the new code gives the same results as
    2.     the old code (except in a few cases on bdiv):
    3.     + Both A and P are undefined and thus will not be used for rounding
    4.       after each operation.
    5.     + round() is thus a no-op, unless given extra parameters A and P

Infinity and Not a Number

While Math::BigInt has extensive handling of inf and NaN, certain quirks remain.

  • oct()/hex()

    These perl routines currently (as of Perl v.5.8.6) cannot handle passed inf.

    1.     te@linux:~> perl -wle 'print 2 ** 3333'
    2.     Inf
    3.     te@linux:~> perl -wle 'print 2 ** 3333 == 2 ** 3333'
    4.     1
    5.     te@linux:~> perl -wle 'print oct(2 ** 3333)'
    6.     0
    7.     te@linux:~> perl -wle 'print hex(2 ** 3333)'
    8.     Illegal hexadecimal digit 'I' ignored at -e line 1.
    9.     0

    The same problems occur if you pass them Math::BigInt->binf() objects. Since overloading these routines is not possible, this cannot be fixed from Math::BigInt.

INTERNALS

You should neither care about nor depend on the internal representation; it might change without notice. Use ONLY method calls like $x->sign(); instead relying on the internal representation.

MATH LIBRARY

Math with the numbers is done (by default) by a module called Math::BigInt::Calc . This is equivalent to saying:

  1.     use Math::BigInt try => 'Calc';

You can change this backend library by using:

  1.     use Math::BigInt try => 'GMP';

Note: General purpose packages should not be explicit about the library to use; let the script author decide which is best.

If your script works with huge numbers and Calc is too slow for them, you can also for the loading of one of these libraries and if none of them can be used, the code dies:

  1.     use Math::BigInt only => 'GMP,Pari';

The following would first try to find Math::BigInt::Foo, then Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:

  1.     use Math::BigInt try => 'Foo,Math::BigInt::Bar';

The library that is loaded last is used. Note that this can be overwritten at any time by loading a different library, and numbers constructed with different libraries cannot be used in math operations together.

What library to use?

Note: General purpose packages should not be explicit about the library to use; let the script author decide which is best.

Math::BigInt::GMP and Math::BigInt::Pari are in cases involving big numbers much faster than Calc, however it is slower when dealing with very small numbers (less than about 20 digits) and when converting very large numbers to decimal (for instance for printing, rounding, calculating their length in decimal etc).

So please select carefully what library you want to use.

Different low-level libraries use different formats to store the numbers. However, you should NOT depend on the number having a specific format internally.

See the respective math library module documentation for further details.

SIGN

The sign is either '+', '-', 'NaN', '+inf' or '-inf'.

A sign of 'NaN' is used to represent the result when input arguments are not numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively minus infinity. You get '+inf' when dividing a positive number by 0, and '-inf' when dividing any negative number by 0.

EXAMPLES

  1.   use Math::BigInt;
  3.   sub bigint { Math::BigInt->new(shift); }
  5.   $x = Math::BigInt->bstr("1234")       # string "1234"
  6.   $x = "$x";                            # same as bstr()
  7.   $x = Math::BigInt->bneg("1234");      # Math::BigInt "-1234"
  8.   $x = Math::BigInt->babs("-12345");    # Math::BigInt "12345"
  9.   $x = Math::BigInt->bnorm("-0.00");    # Math::BigInt "0"
  10.   $x = bigint(1) + bigint(2);           # Math::BigInt "3"
  11.   $x = bigint(1) + "2";                 # ditto (auto-Math::BigIntify of "2")
  12.   $x = bigint(1);                       # Math::BigInt "1"
  13.   $x = $x + 5 / 2;                      # Math::BigInt "3"
  14.   $x = $x ** 3;                         # Math::BigInt "27"
  15.   $x *= 2;                              # Math::BigInt "54"
  16.   $x = Math::BigInt->new(0);            # Math::BigInt "0"
  17.   $x--;                                 # Math::BigInt "-1"
  18.   $x = Math::BigInt->badd(4,5)          # Math::BigInt "9"
  19.   print $x->bsstr();                    # 9e+0

Examples for rounding:

  1.   use Math::BigFloat;
  2.   use Test::More;
  4.   $x = Math::BigFloat->new(123.4567);
  5.   $y = Math::BigFloat->new(123.456789);
  6.   Math::BigFloat->accuracy(4);          # no more A than 4
  8.   is ($x->copy()->bround(),123.4);      # even rounding
  9.   print $x->copy()->bround(),"\n";      # 123.4
  10.   Math::BigFloat->round_mode('odd');    # round to odd
  11.   print $x->copy()->bround(),"\n";      # 123.5
  12.   Math::BigFloat->accuracy(5);          # no more A than 5
  13.   Math::BigFloat->round_mode('odd');    # round to odd
  14.   print $x->copy()->bround(),"\n";      # 123.46
  15.   $y = $x->copy()->bround(4),"\n";      # A = 4: 123.4
  16.   print "$y, ",$y->accuracy(),"\n";     # 123.4, 4
  18.   Math::BigFloat->accuracy(undef);      # A not important now
  19.   Math::BigFloat->precision(2);         # P important
  20.   print $x->copy()->bnorm(),"\n";       # 123.46
  21.   print $x->copy()->bround(),"\n";      # 123.46

Examples for converting:

  1.   my $x = Math::BigInt->new('0b1'.'01' x 123);
  2.   print "bin: ",$x->as_bin()," hex:",$x->as_hex()," dec: ",$x,"\n";

Autocreating constants

After use Math::BigInt ':constant' all the integer decimal, hexadecimal and binary constants in the given scope are converted to Math::BigInt . This conversion happens at compile time.

In particular,

  1.   perl -MMath::BigInt=:constant -e 'print 2**100,"\n"'

prints the integer value of 2**100 . Note that without conversion of constants the expression 2**100 is calculated using Perl scalars.

Please note that strings and floating point constants are not affected, so that

  1.     use Math::BigInt qw/:constant/;
  3.     $x = 1234567890123456789012345678901234567890
  4.             + 123456789123456789;
  5.     $y = '1234567890123456789012345678901234567890'
  6.             + '123456789123456789';

does not give you what you expect. You need an explicit Math::BigInt->new() around one of the operands. You should also quote large constants to protect loss of precision:

  1.     use Math::BigInt;
  3.     $x = Math::BigInt->new('1234567889123456789123456789123456789');

Without the quotes Perl would convert the large number to a floating point constant at compile time and then hand the result to Math::BigInt, which results in an truncated result or a NaN.

This also applies to integers that look like floating point constants:

  1.     use Math::BigInt ':constant';
  3.     print ref(123e2),"\n";
  4.     print ref(123.2e2),"\n";

prints nothing but newlines. Use either bignum or Math::BigFloat to get this to work.

PERFORMANCE

Using the form $x += $y; etc over $x = $x + $y is faster, since a copy of $x must be made in the second case. For long numbers, the copy can eat up to 20% of the work (in the case of addition/subtraction, less for multiplication/division). If $y is very small compared to $x, the form $x += $y is MUCH faster than $x = $x + $y since making the copy of $x takes more time then the actual addition.

With a technique called copy-on-write, the cost of copying with overload could be minimized or even completely avoided. A test implementation of COW did show performance gains for overloaded math, but introduced a performance loss due to a constant overhead for all other operations. So Math::BigInt does currently not COW.

The rewritten version of this module (vs. v0.01) is slower on certain operations, like new() , bstr() and numify() . The reason are that it does now more work and handles much more cases. The time spent in these operations is usually gained in the other math operations so that code on the average should get (much) faster. If they don't, please contact the author.

Some operations may be slower for small numbers, but are significantly faster for big numbers. Other operations are now constant (O(1), like bneg() , babs() etc), instead of O(N) and thus nearly always take much less time. These optimizations were done on purpose.

If you find the Calc module to slow, try to install any of the replacement modules and see if they help you.

Alternative math libraries

You can use an alternative library to drive Math::BigInt. See the section MATH LIBRARY for more information.

For more benchmark results see http://bloodgate.com/perl/benchmarks.html.

SUBCLASSING

Subclassing Math::BigInt

The basic design of Math::BigInt allows simple subclasses with very little work, as long as a few simple rules are followed:

  • The public API must remain consistent, i.e. if a sub-class is overloading addition, the sub-class must use the same name, in this case badd(). The reason for this is that Math::BigInt is optimized to call the object methods directly.

  • The private object hash keys like $x->{sign} may not be changed, but additional keys can be added, like $x->{_custom} .

  • Accessor functions are available for all existing object hash keys and should be used instead of directly accessing the internal hash keys. The reason for this is that Math::BigInt itself has a pluggable interface which permits it to support different storage methods.

More complex sub-classes may have to replicate more of the logic internal of Math::BigInt if they need to change more basic behaviors. A subclass that needs to merely change the output only needs to overload bstr() .

All other object methods and overloaded functions can be directly inherited from the parent class.

At the very minimum, any subclass needs to provide its own new() and can store additional hash keys in the object. There are also some package globals that must be defined, e.g.:

  1.     # Globals
  2.     $accuracy = undef;
  3.     $precision = -2;       # round to 2 decimal places
  4.     $round_mode = 'even';
  5.     $div_scale = 40;

Additionally, you might want to provide the following two globals to allow auto-upgrading and auto-downgrading to work correctly:

  1.     $upgrade = undef;
  2.     $downgrade = undef;

This allows Math::BigInt to correctly retrieve package globals from the subclass, like $SubClass::precision . See t/Math/BigInt/Subclass.pm or t/Math/BigFloat/SubClass.pm completely functional subclass examples.

Don't forget to

  1.     use overload;

in your subclass to automatically inherit the overloading from the parent. If you like, you can change part of the overloading, look at Math::String for an example.

UPGRADING

When used like this:

  1.     use Math::BigInt upgrade => 'Foo::Bar';

certain operations 'upgrade' their calculation and thus the result to the class Foo::Bar. Usually this is used in conjunction with Math::BigFloat:

  1.     use Math::BigInt upgrade => 'Math::BigFloat';

As a shortcut, you can use the module bignum:

  1.     use bignum;

Also good for one-liners:

  1.     perl -Mbignum -le 'print 2 ** 255'

This makes it possible to mix arguments of different classes (as in 2.5 + 2) as well es preserve accuracy (as in sqrt(3)).

Beware: This feature is not fully implemented yet.

Auto-upgrade

The following methods upgrade themselves unconditionally; that is if upgrade is in effect, they always hands up their work:

  1.     div bsqrt blog bexp bpi bsin bcos batan batan2

All other methods upgrade themselves only when one (or all) of their arguments are of the class mentioned in $upgrade.

EXPORTS

Math::BigInt exports nothing by default, but can export the following methods:

  1.     bgcd
  2.     blcm

CAVEATS

Some things might not work as you expect them. Below is documented what is known to be troublesome:

  • Comparing numbers as strings

    Both bstr() and bsstr() as well as stringify via overload drop the leading '+'. This is to be consistent with Perl and to make cmp (especially with overloading) to work as you expect. It also solves problems with Test.pm and Test::More, which stringify arguments before comparing them.

    Mark Biggar said, when asked about to drop the '+' altogether, or make only cmp work:

    1.     I agree (with the first alternative), don't add the '+' on positive
    2.     numbers.  It's not as important anymore with the new internal form
    3.     for numbers.  It made doing things like abs and neg easier, but
    4.     those have to be done differently now anyway.

    So, the following examples now works as expected:

    1.     use Test::More tests => 1;
    2.     use Math::BigInt;
    4.     my $x = Math::BigInt -> new(3*3);
    5.     my $y = Math::BigInt -> new(3*3);
    7.     is($x,3*3, 'multiplication');
    8.     print "$x eq 9" if $x eq $y;
    9.     print "$x eq 9" if $x eq '9';
    10.     print "$x eq 9" if $x eq 3*3;

    Additionally, the following still works:

    1.     print "$x == 9" if $x == $y;
    2.     print "$x == 9" if $x == 9;
    3.     print "$x == 9" if $x == 3*3;

    There is now a bsstr() method to get the string in scientific notation aka 1e+2 instead of 100 . Be advised that overloaded 'eq' always uses bstr() for comparison, but Perl represents some numbers as 100 and others as 1e+308. If in doubt, convert both arguments to Math::BigInt before comparing them as strings:

    1.     use Test::More tests => 3;
    2.     use Math::BigInt;
    4.     $x = Math::BigInt->new('1e56'); $y = 1e56;
    5.     is($x,$y);                     # fails
    6.     is($x->bsstr(),$y);            # okay
    7.     $y = Math::BigInt->new($y);
    8.     is($x,$y);                     # okay

    Alternatively, simply use <=> for comparisons, this always gets it right. There is not yet a way to get a number automatically represented as a string that matches exactly the way Perl represents it.

    See also the section about Infinity and Not a Number for problems in comparing NaNs.

  • int()

    int() returns (at least for Perl v5.7.1 and up) another Math::BigInt, not a Perl scalar:

    1.     $x = Math::BigInt->new(123);
    2.     $y = int($x);                           # 123 as a Math::BigInt
    3.     $x = Math::BigFloat->new(123.45);
    4.     $y = int($x);                           # 123 as a Math::BigFloat

    If you want a real Perl scalar, use numify() :

    1.     $y = $x->numify();                      # 123 as a scalar

    This is seldom necessary, though, because this is done automatically, like when you access an array:

    1.     $z = $array[$x];                        # does work automatically
  • Modifying and =

    Beware of:

    1.     $x = Math::BigFloat->new(5);
    2.     $y = $x;

    This makes a second reference to the same object and stores it in $y. Thus anything that modifies $x (except overloaded operators) also modifies $y, and vice versa. Or in other words, = is only safe if you modify your Math::BigInt objects only via overloaded math. As soon as you use a method call it breaks:

    1.     $x->bmul(2);
    2.     print "$x, $y\n";       # prints '10, 10'

    If you want a true copy of $x, use:

    1.     $y = $x->copy();

    You can also chain the calls like this, this first makes a copy and then multiply it by 2:

    1.     $y = $x->copy()->bmul(2);

    See also the documentation for overload.pm regarding = .

  • Overloading -$x

    The following:

    1.     $x = -$x;

    is slower than

    1.     $x->bneg();

    since overload calls sub($x,0,1); instead of neg($x) . The first variant needs to preserve $x since it does not know that it later gets overwritten. This makes a copy of $x and takes O(N), but $x->bneg() is O(1).

  • Mixing different object types

    With overloaded operators, it is the first (dominating) operand that determines which method is called. Here are some examples showing what actually gets called in various cases.

    1.     use Math::BigInt;
    2.     use Math::BigFloat;
    4.     $mbf  = Math::BigFloat->new(5);
    5.     $mbi2 = Math::BigInt->new(5);
    6.     $mbi  = Math::BigInt->new(2);
    7.                                     # what actually gets called:
    8.     $float = $mbf + $mbi;           # $mbf->badd($mbi)
    9.     $float = $mbf / $mbi;           # $mbf->bdiv($mbi)
    10.     $integer = $mbi + $mbf;         # $mbi->badd($mbf)
    11.     $integer = $mbi2 / $mbi;        # $mbi2->bdiv($mbi)
    12.     $integer = $mbi2 / $mbf;        # $mbi2->bdiv($mbf)

    For instance, Math::BigInt->bdiv() always returns a Math::BigInt, regardless of whether the second operant is a Math::BigFloat. To get a Math::BigFloat you either need to call the operation manually, make sure each operand already is a Math::BigFloat, or cast to that type via Math::BigFloat->new():

    1.     $float = Math::BigFloat->new($mbi2) / $mbi;     # = 2.5

    Beware of casting the entire expression, as this would cast the result, at which point it is too late:

    1.     $float = Math::BigFloat->new($mbi2 / $mbi);     # = 2

    Beware also of the order of more complicated expressions like:

    1.     $integer = ($mbi2 + $mbi) / $mbf;               # int / float => int
    2.     $integer = $mbi2 / Math::BigFloat->new($mbi);   # ditto

    If in doubt, break the expression into simpler terms, or cast all operands to the desired resulting type.

    Scalar values are a bit different, since:

    1.     $float = 2 + $mbf;
    2.     $float = $mbf + 2;

    both result in the proper type due to the way the overloaded math works.

    This section also applies to other overloaded math packages, like Math::String.

    One solution to you problem might be autoupgrading|upgrading. See the pragmas bignum, bigint and bigrat for an easy way to do this.

BUGS

Please report any bugs or feature requests to bug-math-bigint at rt.cpan.org , or through the web interface at https://rt.cpan.org/Ticket/Create.html?Queue=Math-BigInt (requires login). We will be notified, and then you'll automatically be notified of progress on your bug as I make changes.

SUPPORT

You can find documentation for this module with the perldoc command.

  1.     perldoc Math::BigInt

You can also look for information at:

LICENSE

This program is free software; you may redistribute it and/or modify it under the same terms as Perl itself.

SEE ALSO

Math::BigFloat and Math::BigRat as well as the backends Math::BigInt::FastCalc, Math::BigInt::GMP, and Math::BigInt::Pari.

The pragmas bignum, bigint and bigrat also might be of interest because they solve the autoupgrading/downgrading issue, at least partly.

AUTHORS

Many people contributed in one or more ways to the final beast, see the file CREDITS for an (incomplete) list. If you miss your name, please drop me a mail. Thank you!

Page index